100 rem ■tinylog jr5hjj■
110 cls
120 rem ■運用パターン1読込■
130 op1flg=0
140 print"tinylog起動!"
150 open "opp.csv" for input as #1
160 while eof(1)=0
170 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
180 select case iopn
190 case 1:
200 opn=iopn:opn$=iopn$:mycall$=imycall$:myqth$=imyqth$:myrig$=imyrig$:mypow=imypow:myant$=imyant$:frq=ifrq:mode$=imode$:qsl$=iqsl$:rem1$=irem1$
210 gosub 760
220 print"上記運用パターン1を読込しました"
230 op1flg=1
240 end select
250 wend
260 close #1
270 select case op1flg
280 case 0:
290 color col(10):rem 赤
300 print"起動時に読込するopp.csvに"
310 print"運用パターン1が保存されていません"
320 print"自局データで運用パターン1を設定し"
330 print"保存してください"
340 color col(15):rem 白
350 opn=1
360 end select
370 rem ■main■
380 color col(15):rem 白
390 print""
400 print"tinylog v20250809"
410 color rgb(255,127,0):rem 橙
420 print"運用パターン番号";opn;opn$
430 color col(14):rem ?
440 print frq;"MHz";mode$;mypow;"W ";myqth$
450 color col(13):rem 水色
460 print"1自局データ表示  6運用パターン読込"
470 print"2交信データ入力  7運用パターン削除"
480 print"3交信記録検索   8QSLカード管理"
490 print"4自局データ設定  9ファイルコピー"
500 print"5運用パターン保存 0終了"
510 color col(15):rem 白
520 input"番号をどうぞ";jn
530 select case jn
540 case 1:
550 gosub 760
560 case 2:
570 gosub 930
580 case 3:
590 gosub 2610
600 case 4:
610 gosub 2870
620 case 5:
630 gosub 3340
640 case 6:
650 gosub 3750
660 case 7:
670 gosub 4000
680 case 8:
690 gosub 4590
700 case 9:
710 gosub 5560
720 case 0:
730 goto 5690
740 end select
750 goto 370
760 rem ■自局データ表示■
770 color rgb(255,127,0):rem 橙
780 print""
790 print"1運用パターン番号 ";opn
800 color col(14):rem 黄
810 print"2運用パターン名称 ";opn$
820 print"3自局コールサイン ";mycall$
830 print"4自局運用場所 ";myqth$
840 print"5自局無線機 ";myrig$
850 print"6自局空中線電力 ";mypow;"W"
860 print"7自局アンテナ ";myant$
870 print"8運用周波数 ";frq;"MHz"
880 print"9モード ";mode$
890 print"10QSLカード ";qsl$
900 print"11備考1 ";rem1$
910 color col(15):rem 白
920 return
930 rem ■交信データ入力■
940 qdiflg=1
950 while qdiflg=1
960 print""
970 if frq=0 or mode$="" then goto 980 else goto 1000
980 color col(10):rem 赤
990 print"★自局データ確認してください★ "
1000 color rgb(255,127,0):rem 橙
1010 print "運用パターン番号";opn;opn$
1020 color col(14):rem ?
1030 print myrig$;frq;mode$;mypow;"W";" ";qsl$
1040 print myant$;" ";myqth$
1050 color col(15):rem 白
1060 print"相手局 送ったレポ もらったレポ 備考2の順に入力"
1070 print"(r同上、d指定削除、dd前削除、m自局、0戻る、?)"
1080 color col(12):rem 緑
1090 input qsod$
1100 if qsod$="0" then qdiflg=0
1110 if qsod$="d" then gosub 1970
1120 if qsod$="dd" then drecn=recn:gosub 2040
1130 if qsod$="m" then gosub 760
1140 if qsod$="fm-" then mode$="FM":goto 1000
1150 if qsod$="ssb-" then mode$="SSB":goto 1000
1160 if qsod$="cw-" then mode$="CW":goto 1000
1170 if qsod$="am-" then mode$="AM":goto 1000
1180 if qsod$="?" or qsod$="？" then print"数字のみで周波数設定可"
1190 if qsod$="?" or qsod$="？" then print"fm-、ssb-、cw-、am-でモード設定可"
1200 if qsod$="?" or qsod$="？" then print"備考2でカードのJ、H、N、E、D指定可"
1205 if qsod$="?" or qsod$="？" then print"相手局のqra、qthは備考2で"
1206 if qsod$="?" or qsod$="？" then print"qra〇〇 qth〇〇市のように入力可":goto 960
1210 if len(qsod$)>2 and instr(qsod$," ")=0 and val(qsod$)=0 then scall$=qsod$:gosub 2650
1220 if val(qsod$)>0 and instr(qsod$," ")=0 then frq=val(qsod$)
1230 qsod$=kacnv$(ucase$(qsod$))
1240 rem 連続半角スペースを1個に減らす
1250 while instr(0,qsod$,"  ")>0
1260 qsod$=rep$(qsod$,"  "," ")
1270 wend
1280 rem 両端の半角スペースを削除
1290 qsod$=trim$(qsod$)
1300 rem 備考2が無い時は -を付加
1310 rem if chcnt(qsod$," ")=2 then qsod$=qsod$+" -"
1320 rem 備考2のエンドマークとして -を付加
1330 qsod$=qsod$+" -"
1340 rem 相手コールサイン抽出
1350 hcall$=left$(qsod$,instr(0,qsod$," ")-1)
1360 rem 送ったレポ抽出
1370 srs$=left$(qsod$,instr(len(hcall$)+2,qsod$," "))
1380 srs$=trim$(right$(srs$,len(srs$)-len(hcall$)-1))
1390 rem もらったレポ抽出
1400 rrs$=left$(qsod$,instr(len(hcall$)+len(srs$)+3,qsod$," "))
1410 rrs$=trim$(right$(rrs$,len(rrs$)-len(hcall$)-len(srs$)-2))
1420 rem 備考2抽出
1430 delf2$=hcall$+" "+srs$+" "+rrs$+" "
1440 re2$=trim$(rep$(qsod$,delf2$,""))
1450 rem 3項目以上入力されたか確認
1460 qsod=len(hcall$)*len(srs$)*len(rrs$)
1470 if qsod<>0 then adflg=1
1480 select case adflg
1490 case 1:
1500 rem 有効な交信記録の時
1510 rem 同上があった時
1520 if hcall$="R" then hcall$=rhcall$
1530 if srs$="R" then srs$=rsrs$
1540 if rrs$="R" then rrs$=rrrs$
1550 if re2$="R -" then re2$=rre2$
1560 rem QSLカード転送判定
1570 kre2$=" "+re2$+" "
1580 cqsl$=""
1590 if instr(0,kre2$," J ") then  cqsl$="J"
1600 if instr(0,kre2$," H ") then  cqsl$="H"
1610 if instr(0,kre2$," N ") then  cqsl$="N"
1620 if instr(0,kre2$," E ") then  cqsl$="E"
1630 if instr(0,kre2$," D ") then  cqsl$="D"
1640 if cqsl$<>"" then swap cqsl$,qsl$
1650 rem print qsl$
1660 rem 記録追記
1670 open "rec.csv" for input as #1
1680 input #1,recn
1690 close #1
1700 recn=recn+1
1710 open "rec.csv" for output as #1
1720 print #1,recn
1730 close #1
1740 open "log.csv" for append as #1
1750 print #1,recn;",";date$;",";time$;",";hcall$;",";srs$;",";rrs$;",";re2$;",";mycall$;",";myqth$;",";myrig$;",";mypow;",";myant$;",";frq;",";mode$;",";qsl$;",";rem1$
1760 close #1
1770 color rgb(255,127,0):rem 橙
1780 print "REC No.";recn
1790 color col(14):rem 黄
1800 print " ";date$;" ";time$
1810 print " ";hcall$;frq;"MHz";mode$
1820 print " ";srs$;" ";rrs$;" ｶｰﾄﾞ";qsl$
1830 print " 備考2 ";re2$
1840 color col(15):rem 白
1850 print"上記交信データを追記しました"
1860 adflg=0
1870 rem 同上用控
1880 rrecn=recn
1890 rhcall$=hcall$
1900 rsrs$=srs$
1910 rrrs$=rrs$
1920 rre2$=re2$
1930 if cqsl$<>"" then swap cqsl$,qsl$
1940 end select
1950 wend
1960 return
1970 rem ■交信データ削除■
1980 drecn=0.5
1990 print""
2000 color col(15):rem 白
2010 print"削除するREC No.をどうぞ"
2015 print"0で戻ります";
2020 color col(12):rem 緑
2030 input drecn
2040 dgo=0
2050 puflg=0
2060 color col(15):rem 白
2070 print"REC No.";drecn;"検索中!"
2080 color col(14):rem 黄
2090 open "log.csv" for input as #1
2100 while eof(1)=0
2110 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
2120 if drecn=irecn then dflg=1 else dflg=0
2130 select case dflg
2140 case 1:
2150 color rgb(255,127,0):rem 橙
2160 print "REC No.";irecn
2170 color col(14):rem ?
2180 print " ";idate$;" ";itime$
2190 print " ";ihcall$;" ";ifrq;"MHz";imode$;" ｶｰﾄﾞ";iqsl$
2200 print " ";isrs$;" ";irrs$;" ";ire2$
2210 puflg=1
2220 end select
2230 wend
2240 close #1
2250 select case puflg
2260 case 0:
2270 color col(11):rem ピンク
2280 print"見つかりませんでした"
2290 case 1:
2300 color col(10):rem 赤
2310 print"上記交信データを削除しますか?"
2320 print"削除する場合は再度REC No.をどうぞ"
2330 print"中止する場合は0を入力してください";
2340 color col(12):rem 緑
2350 input dgo
2360 if dgo=drecn then dgof=1 else dgof=0
2370 select case dgof
2380 case 1:
2390 open "log.csv" for input as #1
2400 open "log.new" for output as #2
2410 while eof(1)=0
2420 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
2430 if drecn=irecn then dflg=1 else dflg=0
2440 select case dflg
2450 case 0:
2460 print #2,irecn;",";idate$;",";itime$;",";ihcall$;",";isrs$;",";irrs$;",";ire2$;",";imycall$;",";imyqth$;",";imyrig$;",";imypow;",";imyant$;",";ifrq;",";imode$;",";iqsl$;",";irem1$
2470 case 1:
2480 end select
2490 wend
2500 close
2510 name "log.csv" as "log.old"
2520 name "log.new" as "log.csv"
2530 color col(11):rem ピンク
2540 print"削除しました"
2550 case else:
2560 color col(12):rem 緑
2570 print"削除しませんでした"
2580 end select
2590 end select
2600 return
2610 rem ■交信記録検索■
2620 print""
2630 color col(12 ):rem 緑
2640 input"検索するコールサインをどうぞ";scall$
2650 color col(15 ):rem 白
2660 print"検索中!"
2670 color col(14):rem ?
2680 scall$=ucase$(scall$)
2690 open "log.csv" for input as #1
2700 while eof(1)=0
2710 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
2720 if instr(0,ihcall$,scall$)<>0 then fflg=1 else fflg=0
2730 select case fflg
2740 case 1
2750 color rgb(255,127,0):rem 橙
2760 print "REC No.";irecn
2770 color col(14):rem ?
2780 print " ";idate$;" ";itime$
2790 print " ";ihcall$;" ";ifrq;"MHz";imode$;" ｶｰﾄﾞ";iqsl$
2800 print " ";isrs$;" ";irrs$;" ";ire2$
2810 end select
2820 wend
2830 close #1
2840 color col(15):rem 白
2850 print"検索終わりました"
2860 return
2870 rem ■自局データ設定■
2880 flg=1
2890 while flg=1
2900 gosub 760
2910 color col(15):rem 白
2920 print"設定対象の番号をどうぞ"
2930 input"0で戻ります";jn
2940 color col(12):rem 緑
2950 select case jn
2960 case 1:
2970 input"運用パターン番号 ";iopn
2980 if iopn>0 then opn=iopn else goto 2970
2990 case 2:
3000 input"運用パターン名称 ";iopn$
3010 if iopn$<>"" then opn$=kacnv$(ucase$(iopn$))
3020 case 3:
3030 input"自局コールサイン ";imycall$
3040 if imycall$<>"" then mycall$=kacnv$(ucase$(imycall$))
3050 case 4:
3060 input"自局運用場所 ";imyqth$
3070 if imyqth$<>"" then myqth$=kacnv$(ucase$(imyqth$))
3080 case 5:
3090 input"自局無線機 ";imyrig$
3100 if imyrig$<>"" then myrig$=kacnv$(ucase$(imyrig$))
3110 case 6:
3120 input"自局空中線電力(W) ";imypow
3130 if imypow<>0 then mypow=imypow
3140 case 7:
3150 input"自局アンテナ ";imyant$
3160 if imyant$<>"" then myant$=kacnv$(ucase$(imyant$))
3170 case 8:
3180 input"運用周波数(MHz) ";ifrq
3190 if ifrq<>0 then frq=ifrq
3200 case 9:
3210 input"モード ";imode$
3220 if imode$<>"" then mode$=kacnv$(ucase$(imode$))
3230 case 10:
3240 input"QSLカード";iqsl$
3250 if iqsl$<>"" then qsl$=kacnv$(ucase$(iqsl$))
3260 case 11:
3270 input"備考1 ";irem1$
3280 if irem1$<>"" then rem1$=kacnv$(ucase$(irem1$)) else rem1$="-"
3290 case 0:
3300 flg=0
3310 end select
3320 wend
3330 return
3340 rem ■運用パターン保存■
3350 if rem1$="" then rem1$="-"
3360 eflg=0:rem 既存フラグを0セット
3370 owflg=0:rem 上書きフラグを0セット
3380 open "opp.csv" for input as #1
3390 while eof(1)=0
3400 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
3410 if iopn=opn then eflg=1
3420 wend
3430 close #1
3440 select case eflg
3450 case 0:
3460 open "opp.csv" for append as #1
3470 print #1,date$;",";time$;",";opn;",";opn$;",";mycall$;",";myqth$;",";myrig$;",";mypow;",";myant$;",";frq;",";mode$;",";qsl$;",";rem1$
3480 close #1
3490 gosub 760
3500 color col(11):rem ピンク
3510 print"上記パターンを追加保存しました"
3520 case 1:
3530 open "opp.csv" for input as #1
3540 open "opp.new" for output as #2
3550 while eof(1)=0
3560 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
3570 oopn=iopn:oopn$=iopn$:omycall$=imycall$:omyqth$=imyqth$:omyrig$=imyrig$:omypow=imypow:omyant$=imyant$:ofrq=ifrq:omode$=imode$:oqsl$=iqsl$:orem1$=irem1$
3580 if iopn=opn then owflg=1
3590 select case owflg
3600 case 1:
3610 oopn=opn:oopn$=opn$:omycall$=mycall$:omyqth$=myqth$:omyrig$=myrig$:omypow=mypow:omyant$=myant$:ofrq=frq:omode$=mode$:oqsl$=qsl$:orem1$=rem1$
3620 owflg=0
3630 end select
3640 print #2,date$;",";time$;",";oopn;",";oopn$;",";omycall$;",";omyqth$;",";omyrig$;",";omypow;",";omyant$;",";ofrq;",";omode$;",";oqsl$;",";orem1$
3650 wend
3660 close #1
3670 close #2
3680 name "opp.csv" as "opp.old"
3690 name "opp.new" as "opp.csv"
3700 gosub 760
3710 color col(11):rem ピンク
3720 print"上記パターンを上書き保存しました"
3730 end select
3740 return
3750 rem ■運用パターン読込■
3760 gosub 4380
3770 jn=0.5
3780 print""
3790 print"読込する番号をどうぞ"
3800 input"0で戻ります";jn
3810 select case jn
3820 case 0:
3830 return
3840 case else:
3850 open "opp.csv" for input as #1
3860 while eof(1)=0
3870 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
3880 if jn=iopn then chflg=1 else chflg=0
3890 select case chflg
3900 case 1:
3910 opn=iopn:opn$=iopn$:mycall$=imycall$:myqth$=imyqth$:myrig$=imyrig$:mypow=imypow:myant$=imyant$:frq=ifrq:mode$=imode$:qsl$=iqsl$:rem1$=irem1$
3920 gosub 760
3930 color col(11):rem ピンク
3940 print"上記パターンを読込しました"
3950 end select
3960 wend
3970 close #1
3980 end select
3990 return
4000 rem ■運用パターン削除■
4010 jn=0:print""
4020 print"削除する番号をどうぞ"
4030 print"0で戻ります";
4040 color col(12):rem 緑
4050 input jn
4060 if jn=0 then goto 4070 else goto 4080
4070 return
4080 open "opp.csv" for input as #1
4090 open "opp.new" for output as #2
4100 while eof(1)=0
4110 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
4120 if iopn=jn then dflg=1 else dflg=0
4130 select case dflg
4140 case 0:
4150 print #2,idate$;",";itime$;",";iopn;",";iopn$;",";imycall$;",";imyqth$;",";imyrig$;",";imypow;",";imyant$;",";ifrq;",";imode$;",";iqsl$;",";irem1$
4160 case 1:
4170 color col(14):rem 黄
4180 print""
4190 print"1運用パターン番号 ";iopn
4200 print"2運用パターン名称 ";iopn$
4210 print"3自局コールサイン ";imycall$
4220 print"4自局運用場所 ";imyqth$
4230 print"5自局無線機";imyrig$
4240 print"6自局空中線電力 ";imypow;"W"
4250 print"7自局アンテナ ";imyant$
4260 print"8運用周波数 ";ifrq;"MHz"
4270 print"9モード ";imode$
4280 print"10QSLカード ";iqsl$
4290 print"11備考1 ";irem1$
4300 color col(10):rem 赤
4310 print"上記パターンを削除しました"
4320 end select
4330 wend
4340 close #1,#2
4350 name "opp.csv" as "opp.old"
4360 name "opp.new" as "opp.csv"
4370 return
4380 rem ■運用パターンリスト表示■
4390 color col(14):rem 黄
4400 print""
4410 print"運用パターンリスト"
4420 open "opp.csv" for input as #1
4430 while eof(1)=0
4440 input #1,idate$,itime$,iopn,iopn$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
4450 print""
4460 color rgb(255,127,0):rem 橙
4470 print"パターン番号";iopn;iopn$
4480 color col(14):rem ?
4490 print " 保存日時 ";idate$;" ";itime$
4500 print " コールサイン ";imycall$;" ";imyqth$
4510 print " ";imyrig$;imypow;"W ";imyant$
4520 print " ";ifrq;"MHz ";imode$;" ｶｰﾄﾞ ";iqsl$
4530 print " ";irem1$
4540 pose$=inkey$:if pose$="" then goto 4540
4550 wend
4560 close #1
4570 color col(15):rem 白
4580 return
4590 rem ■QSLカード■
4600 scall$="-"
4610 while scall$<>"0"
4620 color col(15):rem 白
4630 print""
4640 print"コールサインをどうぞ"
4650 print"0で戻ります";
4660 color col(12):rem 緑
4670 input scall$
4680 if scall$="0" then goto 5550
4690 print"検索中!"
4700 color col(14):rem 黄
4710 scall$=kacnv$(ucase$(scall$))
4720 gosub 5390
4730 eqsln=0.5
4740 print""
4750 color col(15):rem 白
4760 print"呼び出すREC No.をどうぞ"
4770 input"0で戻ります";eqsln
4780 if eqsln=0 then goto 5370
4790 input"設定内容(j*等)をどうぞ";eqsl$
4800 eqsl$=kacnv$(ucase$(eqsl$))
4810 eqslgo=0
4820 puflg=0
4830 color col(14):rem 黄
4840 open "log.csv" for input as #1
4850 while eof(1)=0
4860 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
4870 if eqsln=irecn then eqslflg=1 else eqslflg=0
4880 select case eqslflg
4890 case 1:
4900 color rgb(255,127,0):rem 橙
4910 print "REC No.";irecn
4920 color col(14):rem ?
4930 print " ";idate$;" ";itime$
4940 print " ";ihcall$;" ";ifrq;"MHz";imode$;" ｶｰﾄﾞ";iqsl$
4950 puflg=1
4960 end select
4970 wend
4980 close #1
4990 select case puflg
5000 case 0:
5010 color col(11):rem ピンク
5020 print"見つかりませんでした"
5030 case 1:
5040 color col(10):rem 赤
5050 print"上記交信のQSL記録を";
5060 color col(12):rem 緑
5070 print eqsl$;
5080 color col(10):rem 赤
5090 print"に設定します"
5100 print"実行する場合はREC　No.を入力"
5110 input"中止する場合は0を入力してください";eqslgo
5120 if eqslgo=eqsln then eqgof=1 else eqgof=0
5130 select case eqgof
5140 case 1:
5150 open "log.csv" for input as #1
5160 open "log.new" for output as #2
5170 while eof(1)=0
5180 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
5190 if eqsln=irecn then eflg=1 else eflg=0
5200 select case eflg
5210 case 0:
5220 print #2,irecn;",";idate$;",";itime$;",";ihcall$;",";isrs$;",";irrs$;",";ire2$;",";imycall$;",";imyqth$;",";imyrig$;",";imypow;",";imyant$;",";ifrq;",";imode$;",";iqsl$;",";irem1$
5230 case 1:
5240 print #2,irecn;",";idate$;",";itime$;",";ihcall$;",";isrs$;",";irrs$;",";ire2$;",";imycall$;",";imyqth$;",";imyrig$;",";imypow;",";imyant$;",";ifrq;",";imode$;",";eqsl$;",";irem1$
5250 end select
5260 wend
5270 close
5280 name "log.csv" as "log.old"
5290 name "log.new" as "log.csv"
5300 color col(11):rem ピンク
5310 print"設定しました"
5320 case else:
5330 color col(12):rem 緑
5340 print"設定しませんでした"
5350 end select
5360 end select
5370 wend
5380 return
5390 open "log.csv" for input as #1
5400 while eof(1)=0
5410 input #1,irecn,idate$,itime$,ihcall$,isrs$,irrs$,ire2$,imycall$,imyqth$,imyrig$,imypow,imyant$,ifrq,imode$,iqsl$,irem1$
5420 if instr(0,ihcall$,scall$)<>0 then fflg=1 else fflg=0
5430 select case fflg
5440 case 1
5450 color rgb(255,127,0):rem 橙
5460 print "REC No.";irecn
5470 color col(14):rem ?
5480 print " ";idate$;" ";itime$
5490 print " ";ihcall$;" ";ifrq;"MHz";imode$;" ｶｰﾄﾞ";iqsl$
5500 end select
5510 wend
5520 close #1
5530 color col(15):rem 白
5540 print"検索終わりました"
5550 return
5560 rem ■ファイルコピー■
5570 print""
5580 print"Downloadフォルダへ"
5590 print"ファイル名　 (サイズ)"
5600 print"rec.csv";"(";lof("rec.csv");")"
5610 print"opp.csv";"(";lof("opp.csv");")"
5620 print"log.csv";"(";lof("log.csv");")"
5630 cpy$=rep$(curdir$(0),"Android/data/and.basf/files/","")+"Download/"
5640 copy"opp.csv",cpy$+"opp.csv"
5650 copy"rec.csv",cpy$+"rec.csv"
5660 copy"log.csv",cpy$+"log.csv"
5670 print"コピーしました"
5680 return
5690 rem ■終了■
5700 copy"opp.csv","opp.bak"
5710 copy"rec.csv","rec.bak"
5720 copy"log.csv","log.bak"
5730 color col(15):rem 白
5740 print"73!88!"
5750 end